Actually you can do this natively in the drawing API, but only from flash player 10.

There are two ways to do it.

The old API style in fp10, with the new bitmap stroke:

http://help.adobe.com/en_US/AS3LCR/Flash_10.0/flash/display/Graphics.h tml#lineBitmapStyle()

or

using the IGraphicsData object approach:

create a GraphicsStroke

and assign its fill to be a new GraphicsBitmapFill

that's pretty cool.

but it's not what they're using at fantasticcontraptions.

i think i could create that blue line (water rod) using a movieclip (of an animated horizontal long blue line) that contains a child mask movieclip that masks the blue animated line.  by rotating the main movieclip and than sizing the mask i could create that effect.

the wood rod could be easily done using the lineBitmapStyle() method.

I just threw together a quick proof of concept for the last technique I described...using some similar to the branch image from that earlier link. The swf is attached. Just click around the stage.

I didn't get too sophisticated here.... so no mouse dragging of the circles  etc although that would be easy to add in.

Once its drawn via the drawing API its basically just the native renderer that get's sluggish with the animation updates if you add too much. All the bitmapdata transformations are being done at the native level for the updates, but it can get quite cumbersome/cpu intensive if you put too much on stage. I suspect it might be faster under these conditions if the drawn content was vector data, because you can loop through thousands of drawing commands very quickly.

BranchBitmap is a library bitmap set to export on frame 1 with BranchBitmap as the class name.

The code for this is :

var segments:Sprite=new Sprite()
addChild(segments)
var connectors:Sprite = new Sprite();
addChild(connectors);

var points:Array=[];

stage.addEventListener(MouseEvent.CLICK, clickhandler)
stage.addEventListener(Event.ENTER_FRAME,frameupdater);


function clickhandler(e:MouseEvent):void{
    points.push(new Point(e.stageX,e.stageY));
    connectors.graphics.beginFill(0xff0000,.8);
    connectors.graphics.drawCircle(e.stageX,e.stageY,15);
    drawNewSegment()
}
var lastPoint:Point;
var scrollwidth:uint=2;


var branchBitmapData:BitmapData = new BranchBitmap(247,52);
var scrollpixels:BitmapData = new BitmapData(scrollwidth,branchBitmapData.height)

function frameupdater(e:Event):void{
    branchBitmapData.lock();
    var rect:Rectangle = branchBitmapData.rect;
    rect.x=branchBitmapData.width-scrollwidth;
    rect.width=scrollwidth;
    scrollpixels.copyPixels(branchBitmapData,rect,new Point(0,0))
    branchBitmapData.scroll(1,0)
    branchBitmapData.copyPixels(scrollpixels,scrollpixels.rect,new Point(0,0))
    branchBitmapData.unlock();
}
function drawNewSegment():void{
    
    if (points.length>1){
        if (!lastPoint) lastPoint= points[0];
        var latestPoint:Point = points[points.length-1];
        var diff:Point = latestPoint.subtract(lastPoint);
        var angle:Number = Math.atan2(diff.y,diff.x);
        var baseRectangle:Rectangle = new Rectangle (lastPoint.x, lastPoint.y-branchBitmapData.height/2,Point.distance(lastPoint,latestPoint),branchBitmapData.height);
        var drawingPoints:Array=[];
        var drawingMatrix:Matrix = new Matrix();
        var bitmapMatrix:Matrix=new Matrix();
        bitmapMatrix.translate(0,-branchBitmapData.height/2)
        drawingMatrix.translate(-lastPoint.x,-lastPoint.y);
        drawingMatrix.rotate(angle);
        bitmapMatrix.rotate(angle);
        drawingMatrix.translate(lastPoint.x,lastPoint.y);
        bitmapMatrix.translate(lastPoint.x,lastPoint.y);
        //DEBUG: segments.graphics.lineStyle(0,0,1);
        segments.graphics.beginBitmapFill(branchBitmapData,bitmapMatrix,true,true)
        var p:Point = drawingMatrix.transformPoint(baseRectangle.topLeft);
        var sp:Point =p;
        segments.graphics.moveTo(p.x,p.y);
        p=drawingMatrix.transformPoint(new Point(baseRectangle.bottomRight.x,baseRectangle.y));
        segments.graphics.lineTo(p.x,p.y);
        p=drawingMatrix.transformPoint(baseRectangle.bottomRight);
        segments.graphics.lineTo(p.x,p.y);
        p=drawingMatrix.transformPoint(new Point(baseRectangle.x,baseRectangle.bottomRight.y));
        segments.graphics.lineTo(p.x,p.y);
        segments.graphics.lineTo(sp.x,sp.y);
        lastPoint= latestPoint
        
    }
    
}