Not a workaround, but a tool: use Edit -> Paste in Place

Oh, I misunderstood entirely. Nevermind! I try to avoid scaling raster images in ID, so I have no idea whatsoever how you'd do this, or if it's even possible.

Perhaps our intrepid original poster is unfamiliar with InDesign's handy Fit Content to Frame and Fit Frame to Content tools...

Our intrepid original poster is being very patient and polite yet nobody is helping. It is very true that Quark will easily handle moving imported graphics around by allowing them to be cut from one frame and pasted into another without losing track of the original image directory. This saves a the work of re-importing and "fitting to frame" which isn't necessarily how the image has been sized anyway! I would love to learn if InDesign can handle this because it would simplify the job considerably if a situation occurs such

as the orignal poster described.

What Joel says is explained:

http://indesignsecrets.com/how-frame-fitting-options-affect-paste-into .php

Using the eyedropper tool on the frame of the source picture can fix it.

I have been struggling with this issue as well.

As proposed using the selection tool and "paste into" seems to do the job.

However it paste the entire frame into the new frame, which is not always what you want.

A clever person made a script (I cannot find his name) which do the job (behind the scene it pastes into and removes the original frame):

___

tell application "Adobe InDesign CS5"
    activate
    set mydoc to active document
    set myFrame to selection
   
    --make sure there is a selection
    if myFrame is {} then
        display dialog "Select a frame and try again"
        return
    end if
   
    --make sure the frame has been copied
    try
        paste into
    on error
        display dialog "Clipboard is empty, copy a frame with an image and try again"
        return
    end try
   
    --the pasted item
    set myItems to all page items of item 1 of myFrame
   
    --test for a frame with an image 1 means an image or an empty frame
    if (count of myItems) is 1 then
        delete item 1 of myItems
        display dialog "Copy a frame with an image and try again"
        return
    end if
   
    --item 2 is the image
    select item 2 of myItems
    copy
    --delete the image's frame
    delete item 1 of myItems
    --select the original frame
    select myFrame
    paste into
end tell

___

In CS1 you could do it but in newer versions you need a script. If you try to copy an image from frame 1 to frame 2, and frame 2 is inside the copied image's bounds, pasting into positions the image to the original bounds:

The script puts the image at the same bounds relative to the target box, which might be preferable:

If the target frame is outside of the original's bounds then the image gets centered, which might force you to reposition the image:

Try this for CS3 or CS4. With CS5 images are page items, but in CS3 they were in a seperate graphics class, which is why the CS5 script breaks.

This version works the same way, with the black Selection tool you need to select the source frame, select the destination frame and run the script

tell application "Adobe InDesign CS3"

    activate

    set myDoc to active document

    set myFrame to selection

    --make sure there is a selection

    if myFrame is {} then

        display dialog "Select a frame and try again"

        return

    end if

    --make sure the source frame has been copied

    try

        paste into

    on error

        display dialog "Clipboard is empty, copy a frame with an image and try again"

        return

    end try

    -- check for page items inside of the pasted item

    set myPasted to all page items of item 1 of myFrame

    --if there are none it's an image so delete and show message (this changes in CS5 where a page item can be an image)

    if (count of myPasted) is 0 then

        delete item 1 of myFrame

        display dialog "Copy a frame with an image and try again"

        return

    end if

    --the selection is now the the frame we pasted into, so select the inside frame

    select item 1 of all page items of item 1 of item 1 of selection

    cut

    --paste in place gets the correct position

    paste in place

    --get the temporary paste which we need to delete

    set temp to selection

    --in CS3 to select an image it's item 1 of all graphics and not page items

    set selection to item 1 of all graphics of item 1 of temp

    --cut the image, delete the temp and paste into

    cut

    delete temp

    select myFrame

    paste into

end tell