in answer to your original question this might point you in the right direction

package

{

          import flash.display.Sprite;

          public class Main extends Sprite

          {

                    private static const xml:XML =

                              <period type="first">

                                        <person>

                                                  <name>Last, First</name>

                                                  <grade type="1"> 98 </grade>

                                                  <grade type="2"> 87 </grade>

                                                  <grade type="3"> 62 </grade>

                                                  <grade type="4"> 93 </grade>

                                                  <grade type="5"> 96 </grade>

                                        </person>

                                        <person>

                                                  <name>Last, First</name>

                                                  <grade type="1"> 89 </grade>

                                                  <grade type="2"> 78 </grade>

                                                  <grade type="3"> 26 </grade>

                                                  <grade type="4"> 39 </grade>

                                                  <grade type="5"> 69 </grade>

                                        </person>

                              </period>;

                    public function Main()

                    {

                              var first:int = int.MIN_VALUE;

                              var second:int = int.MIN_VALUE;

                              var grades:XMLList = xml.descendants("grade");

                              for each (var grade:XML in grades)

                              {

                                        var gradeValue:int = parseInt(grade);

                                        if (gradeValue > first)

                                        {

                                                  second = first;

                                                  first = gradeValue;

                                        }

                                        else if (gradeValue > second)

                                        {

                                                  second = gradeValue;

                                        }

                              }

                              trace("highest: " + first);

                              trace("second highest: " + second);

                    }

          }

}

I don't really work in AS2 so you might get a better response on the AS2 forum but this is something i knocked up that seems to work

grades.xml

<period type="first">

                    <person>

                                          <name>Last, First</name>

                                          <grade type="1"> 98 </grade>

                                          <grade type="2"> 87 </grade>

                                          <grade type="3"> 62 </grade>

                                          <grade type="4"> 93 </grade>

                                          <grade type="5"> 96 </grade>

                    </person>

                    <person>

                                          <name>Last, First</name>

                                          <grade type="1"> 89 </grade>

                                          <grade type="2"> 78 </grade>

                                          <grade type="3"> 26 </grade>

                                          <grade type="4"> 39 </grade>

                                          <grade type="5"> 69 </grade>

                    </person>

</period>

<period type="second">

                    <person>

                                          <name>Last, First</name>

                                          <grade type="1"> 56 </grade>

                                          <grade type="2"> 49 </grade>

                                          <grade type="3"> 78 </grade>

                                          <grade type="4"> 99 </grade>

                                          <grade type="5"> 43 </grade>

                    </person>

                    <person>

                                          <name>Last, First</name>

                                          <grade type="1"> 24 </grade>

                                          <grade type="2"> 56 </grade>

                                          <grade type="3"> 73 </grade>

                                          <grade type="4"> 81 </grade>

                                          <grade type="5"> 55 </grade>

                    </person>

</period>

as in frame 1 of fla

trace("start");

var xml:XML = new XML();

xml.ignoreWhite = true;

xml.load("grades.xml");

xml.onLoad = xmlLoaded;

function xmlLoaded(loaded)

{

          if (loaded)

          {

                    var grades:Array = getGrades(this);

                    var first:Number = Number.MIN_VALUE;

                    var second:Number = Number.MIN_VALUE;

                    for (var i:Number = 0; i < grades.length; i++)

                    {

                              var grade:Number = grades[i];

                              if (grade > first)

                              {

                                        second = first;

                                        first = grade;

                              }

                              else if (grade > second)

                              {

                                        second = grade;

                              }

                    }

                    trace("first: " + first);

                    trace("second: " + second);

          }

}

function getGrades(xml:XML):Array

{

          var gradeValues:Array = new Array();

          var periods:Array = xml.childNodes;

          for (var i:Number = 0; i < periods.length; i++)

          {

                    var period:XMLNode = periods[i];

                    var people:Array = period.childNodes;

                    for (var j:Number = 0; j < people.length; j++)

                    {

                              var person:XMLNode = people[j];

                              var grades:Array = person.childNodes;

                              for (var k:Number = 0; k < grades.length; k++)

                              {

                                        var grade:XMLNode = grades[k];

                                        if (grade.nodeName == "grade")

                                        {

                                                  var gradeValue:Number = parseInt(grade.firstChild.toString());

                                                  gradeValues.push(gradeValue);

                                        }

                              }

                    }

          }

          return gradeValues;

}