Could the pasting of all those files be causing the pdf "out of memory" errors I've been experiencing with these files?

I think so. The real downside of pasting is the object becomes part of the file—paste 20, 50mb objects and your ID file will be around a gigabyte

You could try posting my script in the scripting forum and see if you can get a JavaScript translation. The script doesn't open Illustrator, it extracts the pasted object as a PDF via the clipboard.

tell application "Adobe InDesign CS6"

    set myFolder to (choose folder with prompt "Please select the folder you want to save your PDF pages in") as string

    set myDocument to active document

    set pastedimages to all page items of every page item of myDocument

    set imagePaths to {}

    set copiedimages to {}

    repeat with i from 1 to number of items in pastedimages

        set myLink to item 1 of item i of pastedimages

        --pasted files have a nothing link

        if item link of myLink is nothing then

            --set myimage to item i of pastedimages

            select myLink

            set myname to id of myLink

            set hs to horizontal scale of myLink

            set vs to vertical scale of myLink

            set horizontal scale of myLink to 100

            set vertical scale of myLink to 100

            copy

            set horizontal scale of myLink to hs

            set vertical scale of myLink to vs

            tell application "Finder"

                my saveImage(myFolder, myname)

            end tell

            --save the paths and images as lists

            set end of imagePaths to myFolder & myname & ".pdf"

            set end of copiedimages to myLink

        end if

    end repeat

    --link the saved files

    repeat with j from 1 to number of items in imagePaths

        set itemlink to item j of imagePaths

        place alias itemlink on item j of copiedimages

    end repeat

end tell

--writes clipboard to disk

--save folder, image name

on saveImage(theFolder, filename)

    --the save path

    set myPath to theFolder & filename & ".pdf"

    try

        set myFile to (open for access myPath with write permission)

        set eof myFile to 0

        write (the clipboard as «class PDF ») to myFile -- as whatever

        close access myFile

        return (POSIX path of myPath)

    on error

        try

            close access myFile

        end try

        return ""

    end try

end saveImage

Export as pdf, no downsamplng, no compression. Open each pdf page in Illustrator. Run Scoop ($25) from http://worker72a.com/pages/SCP.html. It will extract selected or all images (also collects fonts if needed). These can be edited, resaved, relinked using Illustrator's rotation and scale to match. Or be used back in the Indesign doc.