@Lloyd – that could be done with special PDF workflow software using special "DeviceLink Color Profiles" for color conversion on a case by case basis (e.g. reducing the ink limit on CMY only and preserving the black generation).

For example in the following product:

http://www.callassoftware.com/callas/doku.php/en:support:knowledge:dlp

http://www.callassoftware.com/callas/doku.php/en:products:pdftoolboxse rver:dladdon:devicelinkprofiles

There is a lot of work in generating a good DeviceLink Profile, so you have to pay a considerable amount of money for that technology. Even if Adobe (sometime in the future) would implement DeviceLink technology for InDesign PDF export, you'd have to pay for the profiles.

And usualy using DeviceLink technology is part of the PDF workflow of a printing company.

Uwe

This AppleScript converts any CMYK color that exceeds the document's CMYK profile's total ink limit to Lab than back to CMYK. The conversion enforces the limit.

http://www.zenodesign.com/forum/CheckInk.zip

tell application "Adobe InDesign CS6"

    tell document 1

        --get the total ink allowed by the document's CMYK profile

        try

            set k to make new color with properties {name:"MAXBLACKLAB", space:LAB, color value:{0, 0, 0}}

        end try

        set space of k to CMYK

        set {a, b, c, d} to color value of k

        set inkmax to a + b + c + d as integer

        delete k

        --check the total ink of all document colors

        repeat with x from 1 to count of every color

            if space of color x is CMYK then

                set {a, b, c, d} to color value of color x

                set ti to a + b + c + d as real

                if ti is greater than inkmax then

                    try

                        --convert the color to lab and back to CMYK

                        set space of color x to LAB

                        set space of color x to CMYK

                    end try

                end if

            end if

        end repeat

        display dialog "Total Ink: " & inkmax

    end tell

end tell

There has to be a conversion for total ink to be enforced. Assuming the document has the correct CMYK press profile assigned I can get the profile's total ink max by converting Lab 0|0|0 (absolute black) to CMYK. So US SWOP Coated Lab black converts to 75|68|67|90 (300%), while US Sheetfed Coated allows 350% and black converts to 95|85|85|85. Once I have the document profile's total ink, I can test for colors that exceed it.

When I convert to Lab the appearance of the color doesn't change and when I convert back to CMYK the Lab color is forced into the profile's ink limit.

My script skips the registration color, which can't be altered.