It's fairly simplehere's an example in AS3:

stage.align = StageAlign.TOP_LEFT;
stage.scaleMode = StageScaleMode.NO_SCALE;

var bmp:Tile = new Tile(35, 35);
var tile:BitmapData = new BitmapData(35, 35);
tile.draw(bmp);

shelter.x = stage.stageWidth /2;
shelter.y = stage.stageHeight /2;

function fillBG(evt:Event = null):void {
  graphics.beginBitmapFill(tile);
  graphics.moveTo(0, 0);
  graphics.lineTo(stage.stageWidth, 0);
  graphics.lineTo(stage.stageWidth, stage.stageHeight);
  graphics.lineTo(0, stage.stageHeight);
  graphics.lineTo(0, 0);
  graphics.endFill();
shelter.x = stage.stageWidth /2;
shelter.y = stage.stageHeight /2;
};
fillBG();

stage.addEventListener(Event.RESIZE, fillBG);

In this example shelter is just an impge placed in the center of the stage and tile is just a small image used to fill in the background.  You don't actually need either image. I'd upload an fla but it looks like uploading is no longer an option on this forum.

Here's the AS2 version:

import flash.display.BitmapData;

shelter._x = Stage.width / 2;
shelter._y = Stage.height / 2;

var tile:BitmapData = BitmapData.loadBitmap("tile");

function fillBG()
{
    this.beginBitmapFill(tile);
    this.moveTo(0,0);
    this.lineTo(Stage.width,0);
    this.lineTo(Stage.width,Stage.height);
    this.lineTo(0,Stage.height);
    this.lineTo(0,0);
    this.endFill();
}

fillBG();

var stageL:Object = new Object();
stageL.onResize = function()
{
    fillBG();
    shelter._x = Stage.width / 2;
    shelter._y = Stage.height / 2;
}

Stage.addListener(stageL);

This works just fine.

here's the result of the code  http://www.charliegooddog.org/fullbrowser/AS2/FullBrowserAS2.html

for the complete effect you would also want to add this rule to html css

body {margin:0; padding:0; overflow: auto;}