need help on CFcomponent

[thnguyen-AohJo6]

I have a CFC that use cfautosuggestvalue. here is the code

<cfcomponent output="false">
<cfset THIS.dsn="test">
<!--- Lookup used for auto suggest --->
<cffunction name="lookupArt" access="remote" returntype="array">
<cfargument name="search" type="any" required="false" default="">
<cfargument name="filters" type="any" required="false" default="">
<!--- Define variables --->
<cfset var data="">
<cfset var result=ArrayNew(1)>
<!--- Do search --->
<cfquery datasource="#THIS.dsn#" name="data">
SELECT DISTINCT(term)
FROM term_table
WHERE term LIKE '#ARGUMENTS.search#%'
AND distribution IN (#ARGUMENTS.filters#)
ORDER BY term
</cfquery>

<!--- Build result array --->
<cfloop query="data">
<cfset ArrayAppend(result, term)>
</cfloop>

<!--- And return it --->
<cfreturn result>
</cffunction>
</cfcomponent>

My cfm page:
<cfform action="index.cfm" method="post">
<cfinvoke component="term" method="lookupArt" filters="#filters#" returnvariable="return_filters">
</cfinvoke>
<cfinput type="text"
name="term_name"
autosuggest="cfc:term.lookupArt({cfautosuggestvalue})" size="40" autosuggestminlength="2" />
<cfinput type="submit" name="submit_search" value="Search" />
</cfform>

the problem is that the filters variable passed over to the cfc but would not narrow the search term. I dont know how to get this to work?

Thanks.

[Newsgroup_User]

try this:
autosuggest="cfc:term.lookupArt({cfautosuggestvalue}, '#filters#')"

Azadi Saryev
Sabai-dee.com
http://www.sabai-dee.com/

[thnguyen-AohJo6]

thank you. I also has problems of passing list to cfcomponent. On the cfm page, i have a search and a couple checkbox to check where to search. So I need to pass it as a list over to the cfcomponent for sql. But it keeps on getting errors.

Thanks

[Dan_Bracuk]

cfqueryparam's list attribute will solve your problem for you. However, since the list is coming from checkboxes, you'll have to contend with the possibility that none are selected.

[thnguyen-AohJo6]

thanks. but when i pass over the list to the cfc, it didn't work. Is there anyway to show what's been pass over to cfc? I am wondering what kind string is being passed over.

[Dan_Bracuk]

<cfdump var = "#arguments#">

[Newsgroup_User · Accepted solution]

you can't use a comma-delimited list in a BIND attribute of an
autosuggest element (and of most other new cf tags that support BIND
param) - you need to change the list delimiters to something else, like
| (pipe), using the listchangedelims() cf function.

then in your cfc function you will specify that new delimiter in any
tag/function you use to process the passed list, or you can change the
delimiter back to , (comma)...

if, say, your #filters# var value is "one, two, three", then the
autosuggest attribute in your <cfinput> tag should look like:

autosuggest="cfc:term.lookupArt({cfautosuggestvalue},
'#listchangedelims(filters, "|", ",")#')"

and your query in the cfc function will look like:

WHERE term LIKE <cfqueryparam cfsqltype="cf_sql_varchar"
value="#ARGUMENTS.search#%">
<cfif listlen(arguments.filters)>
AND distribution IN (<cfqueryparam list="yes" separator="|"
value="#ARGUMENTS.filters#">)
</cfif>


Azadi Saryev
Sabai-dee.com
http://www.sabai-dee.com/

[thnguyen-AohJo6]

thank you, the list causes problem because of the comma...problem solved.