A simple scripting idea would be to loop thru the document, find the vector graphics, copy, make a new document to the frame's size, paste, and export that to PDF. This could also be done via JS. Here's an AppleScript annotated. I don't have any error handling, so it might break, but it worked for some simple tests.
Here's a compiled version:
http://www.zenodesign.com/forum/ExportGraphic.zip
--------------------------------------
tell application "Adobe InDesign CC 2014"
--check for vector graphics
set ctest to {PDF, EPS}
--ask for export folder
set fPath to (choose folder with prompt "Please select an Export Destination") as string
--loop thru all graphics
repeat with x in all graphics of active document
--get PDF or EPS
if class of x is in ctest then
--export path with link name
set n to name of item link of x
set myPath to fPath & n & ".pdf"
--the graphic's frame
set f to parent of x
--get the frame's width and height
set {a, b, c, d} to geometric bounds of f
set gw to d - b
set gh to c - a
--copy the art
set selection to f
copy
--makes a new document with no margins to the frame's width and height
my exportGraphic(gw, gh)
--paste, export and close
paste
set view PDF of PDF export preferences to false
export document 1 format PDF type to myPath using PDF export preset "[PDF/X-4:2008]"
tell active document
close saving no
end tell
end if
end repeat
end tell
on exportGraphic(w, h)
tell application "Adobe InDesign CC 2014"
--get the document's color preferences and make a new doc with same
set doc to active document
--set the margins to zero
set properties of margin preferences to {bottom:0.0, left:0.0, right:0.0, top:0.0}
set expdoc to make new document with properties {view preferences:properties of view preferences of doc, CMYK policy:CMYK policy of doc, RGB policy:RGB policy of doc, after blending intent:after blending intent of doc, solid color intent:solid color intent of doc, RGB profile:RGB profile of doc, accurate LAB spots:accurate LAB spots of doc, document preferences:properties of document preferences of doc}
--set the page size
tell active document
set page width of document preferences to w
set page height of document preferences to h
end tell
end tell
end exportGraphic
12
Replies
AdChoices