2 返信 最新の回答 日時: Apr 23, 2017 8:42 PM ユーザー:budat

    オブジェクト効果が PDF/X-4 形式で保存すると失われる

    budat
    budat Apr 21, 2017 2:41 AM

      文字に適用したオブジェクト効果が PDF/X-4 形式で保存すると失われる（InDesign CS6/CC）

      https://helpx.adobe.com/jp/indesign/kb/cq07150205.html

      ↑（文字以外も発生します）

       

      吉田印刷さんでも記事になっていたこの件、Adobeが対応する気が無さそうなので、

      スクリプトで問題パーツを探して「傾斜」を使わずにパーツを傾ける対応しています。

       

      PDF/X-1aを書き出す。

      Creative Cloudを導入せずCS5.5以下を使用する。

      これ以外の対処法はないのでしょうか？

       

      問題が発生する傾斜と透明効果が適用されたパーツを探すAppleScript

      tell application "Adobe InDesign CS6"

        activate

        if (count documents) is equal to 0 then

        display dialog ("ドキュメントを１つ開いてから、" & return & "もう一度実行してください。") buttons "終了" default button 1 with icon caution

        return

        end if

        set itemNum to count of page items of active document

        if itemNum < 1 then

        display dialog ("このドキュメントには" & return & "オブジェクトがありません。") buttons "終了" default button 1 with icon caution

        return

        end if

        set myItems to (every item of all page items of active document whose ((shear angle is not 0) and (class is not group) and ¬

        ((applied of bevel and emboss settings of transparency settings is true) or ¬

        (applied of inner shadow settings of transparency settings is true) or ¬

        (applied of inner glow settings of transparency settings is true) or ¬

        (applied of satin settings of transparency settings is true))))

        if length of myItems > 0 then

        select nothing

        repeat with myItem in myItems

        select myItem --ロックされたオブジェクトは選択されない

        tell active window

        set zoom percentage to 200

        end tell

        display dialog "PDF/X-4書き出しで、" & return & "透明効果が不正に出力される傾斜パーツです！"

        end repeat

        display dialog "PDF/X-4書き出しで、" & return & "透明効果が不正に出力される傾斜パーツが" & return & length of myItems & " 個見つかりました！" buttons "Adobeが悪い" default button 1 with icon caution

        select nothing

        else

        display dialog "PDF/X-4書き出しで、" & return & "透明効果が不正に出力される傾斜パーツは" & return & "ありませんでした。" buttons {"OK"}

        end if

      end tell

        • 1. Re: オブジェクト効果が PDF/X-4 形式で保存すると失われる
          assause Adobe Community Professional & MVP
          assause Apr 21, 2017 6:32 PM (budat への返信)

          確かにこの問題を含めて、CS5やCS6以降から発生したまま現在まで改善していない

          幾つかの不具合があり、頭を悩ませていることが当方もあります。

           

          現状としては、わかっている問題が明確であるものについては、

          該当状況を把握しておいて、それを使用しないことであったり、

          判明している回避方法を使うくらいしかないところです。

           

          この問題を含む、少なくとも都合3件ぐらい深刻なものを当方も把握しているのですが、

          できるだけ早急に改善を期待したいところです。

          なお、うち1件は下記です。

          Opentypeproのルビ字形を使用

          • 2. Re: オブジェクト効果が PDF/X-4 形式で保存すると失われる
            budat Level 1
            budat Apr 23, 2017 8:42 PM (budat への返信)

            こちらの環境では以下のような現象が確認できました。

            スクリーンショット 2017-04-24 12.32.50.png

             

            ただし、効果の適用箇所が「グループ」だと問題が発生しないようです。

            スクリーンショット 2017-04-24 12.35.08.png

             

            AppleScriptでもれなくチェックするには、

              set myItems to ...　のところを

              set myItems to (every item of all page items of active document whose ((shear angle is not 0) and ¬

              ((applied of bevel and emboss settings of transparency settings is true) or ¬

              (applied of inner shadow settings of transparency settings is true) or ¬

              (applied of inner glow settings of transparency settings is true) or ¬

              (applied of satin settings of transparency settings is true) or ¬

              (applied of bevel and emboss settings of fill transparency settings is true) or ¬

              (applied of inner shadow settings of fill transparency settings is true) or ¬

              (applied of inner glow settings of fill transparency settings is true) or ¬

              (applied of satin settings of fill transparency settings is true) or ¬

              (applied of bevel and emboss settings of stroke transparency settings is true) or ¬

              (applied of inner shadow settings of stroke transparency settings is true) or ¬

              (applied of inner glow settings of stroke transparency settings is true) or ¬

              (applied of satin settings of stroke transparency settings is true) or ¬

              (applied of bevel and emboss settings of content transparency settings is true) or ¬

              (applied of inner shadow settings of content transparency settings is true) or ¬

              (applied of inner glow settings of content transparency settings is true) or ¬

              (applied of satin settings of content transparency settings is true) ¬

              )))

            にするとよいかもしれません。