9 Replies Latest reply on Mar 4, 2014 9:11 AM by HeyMikey

    How do I show what styles look like?

    riott.girl Level 1

      I received a file that has over 50 different styles loaded.

       

      I'd like to see what the styles look like.

       

      Is there a way to show this without having to apply each?  A sort of index of styles, sort of what it looks like when viewing fonts in a viewer.

       

      InDesign CS5.

       

      Thanks.

        • 1. Re: How do I show what styles look like?
          rob day Adobe Community Professional & MVP

          You can script it. If you are using OSX this AppleScript adds a page at the end of the active document with a list of document paragraph styles styled:

           

          tell application "Adobe InDesign CS6"

              set stylePage to make page at end of active document

              tell stylePage

                  set t to make text frame with properties {geometric bounds:{0.5, 0.5, 10.5, 8}}

                  set text column count of text frame preferences of t to 3

              end tell

              set s to every paragraph style of active document

              repeat with x in s

                  set sname to name of x

                  set contents of last insertion point of t to return & return & sname

                  set applied paragraph style of paragraph (count of paragraphs of t) of t to x

              end repeat

          end tell

          • 2. Re: How do I show what styles look like?
            Laubender Adobe Community Professional & MVP

            @riott_girl – there is an ExtendScript script (for  Windows and OSX) by Kasyan Servetsky, that  lists the properties and values of every paragraph style in a CSV or TEXT file list:

             

            Kasyan Servetsky

            Export paragraph style description settings

            Script for InDesign CS3–6. Version 3.5

             

            http://kasyan.ho.com.ua/export_styles_description_settings_to_csv.html

             

             

            Uwe

            • 3. Re: How do I show what styles look like?
              rob day Adobe Community Professional & MVP

              Uwe, I think the OP wants to see the styles applied to text rather than a list of properties. So my script does this:

               

              Screen Shot 2014-03-01 at 8.32.26 AM.png

              • 4. Re: How do I show what styles look like?
                Obi-wan Kenobi Adobe Community Professional

                Hi Rob,

                 

                Cool [AS]. Can you do the same thing with character styles?

                • 5. Re: How do I show what styles look like?
                  rob day Adobe Community Professional & MVP

                  Yes. And you might want some extra text for the paragraph styles, which I've included in this version:

                   

                   

                  -------------------------------------------------

                   

                  set pText to ":  The quick brown fox jumps"

                   

                  tell application "Adobe InDesign CS6"

                      set stylePage to make page at end of active document

                      tell stylePage

                          set t to make text frame with properties {geometric bounds:{0.5, 0.5, 10.5, 8}}

                          set text column count of text frame preferences of t to 2

                      end tell

                   

                      set s to every paragraph style of active document

                   

                      set contents of last insertion point of t to "Paragraph Styles"

                      set applied paragraph style of paragraph (count of paragraphs of t) of t to item 2 of s

                   

                      repeat with x in s

                          set sname to name of x

                          set contents of last insertion point of t to return & return & sname & pText

                          set applied paragraph style of paragraph (count of paragraphs of t) of t to x

                      end repeat

                   

                      set c to every character style of active document

                   

                      set contents of last insertion point of t to return & return & return & return & "Character Styles"

                      set applied paragraph style of paragraph (count of paragraphs of t) of t to item 2 of s

                   

                      repeat with i in c

                          set cname to name of i

                          set contents of last insertion point of t to return & return & cname

                          set applied character style of every word of paragraph (count of paragraphs of t) of t to i

                      end repeat

                  end tell

                   

                  ----------------------------------------

                   

                  Screen Shot 2014-03-01 at 9.25.48 AM.png

                   

                  Message was edited by: Rob Day

                  • 6. Re: How do I show what styles look like?
                    riott.girl Level 1

                    Thanks Rob.  Would you happen to have this for Windows?

                     

                    It is exatly what I'm after.

                    • 7. Re: How do I show what styles look like?
                      Obi-wan Kenobi Adobe Community Professional

                      Rob,

                       

                      You're cool! Thanks.

                       

                      I am putting it now in my ID Scripts folder.

                      • 8. Re: How do I show what styles look like?
                        rob day Adobe Community Professional & MVP

                        Would you happen to have this for Windows?

                         

                        You'd have to get it translated to JavaScript. You could ask in the Scripting forum—the code is pretty simple.

                        • 9. Re: How do I show what styles look like?
                          HeyMikey Level 3

                          Hey Rob, this is great! I've got it in my Scripts folder now, just tried it and it's gonna be a lifesaver!

                           

                          Cheers!

                          -Mikey