2 Replies Latest reply on Dec 1, 2016 6:39 AM by DBLjan

    I have a 40 page document and I needed to reduce the page size dimensions. How do I reduce the now oversized text frames to the fit to the new margin sizes without having to manually reduce each text frame by hand.

    GlobalGypsy

      I have a 40 page document and I needed to reduce the page size dimensions. How do I reduce the now oversized text frames to the fit to the new margin sizes without having to manually reduce each text frame by hand.

        • 1. Re: I have a 40 page document and I needed to reduce the page size dimensions. How do I reduce the now oversized text frames to the fit to the new margin sizes without having to manually reduce each text frame by hand.
          Doc Maik Level 4

          I tested it in CS6 with reducing a page from A4 to A5 - it does not work.

          The best option would be to use Liquid Layout with "guide based" method where you place guides on the master page and then set the liquid layout rule to "controlled by master page". Problem/bug here: Indesign does not put the guides correctly if you, for example, change the page format from A4 to A5. Activating "Fit content automatically" and "object based" method also do not help. The resized text frame was always wider than the page margins or even wider than the page.

          Next problem: if the text frames are not linked or at least set to auto-size, you'd get overset text after reducing the page size.

          • 2. Re: I have a 40 page document and I needed to reduce the page size dimensions. How do I reduce the now oversized text frames to the fit to the new margin sizes without having to manually reduce each text frame by hand.
            DBLjan Level 2

            I have an Applescript to move textboxes on all pages around. Just adjust a text frame (as a reference) and all frames will be set to that position/size.

             

             

            tell application "Adobe InDesign CC 2017"
                
                if (count documents) > 0 then
                    set thisdoc to active document
                    set tempsel to selection
                    
                    if length of tempsel = 0 then
                        display dialog "Please choose a reference object." with icon 0 buttons {"Ohno!"} with title "TextboxMover"
                        error number -128
                    end if
                    
                    set mySelection to object reference of item 1 of tempsel
                    set SuperPosSave to geometric bounds of mySelection
                    
                    display dialog "Reference object choosen." & linefeed & linefeed & "Top/Left:" & linefeed & "  X=" & item 2 of SuperPosSave & linefeed & "  Y=" & item 1 of SuperPosSave & linefeed & linefeed & "Set position to all text frames?" buttons {"✘", "✔︎"} default button 1 with icon 2
                    
                    if button returned of result = "✘" then error number -128
                    tell thisdoc
                        repeat with i from 1 to count of pages of thisdoc
                            set myPage to page i of thisdoc
                            tell myPage
                                repeat with mycounter from 1 to (count page items)
                                    set myPageItem to page item mycounter                                              
                                    if class of myPageItem as string = "text frame" then
                                        if locked of myPageItem = false then
                                            move myPageItem to {item 2 of SuperPosSave, item 1 of SuperPosSave}
                                               set geometric bounds of myPageItem to SuperPosSave
                                        end if
                                    end if
                                    
                                end repeat
                            end tell
                        end repeat
                    end tell
                end if
                
            end tell
            
            1 person found this helpful