7 Replies Latest reply on Mar 8, 2017 1:09 PM by rob day

    Can't unembed link

    Kenneth C. Benson Level 4

      I inherited a document with three signature graphics, all of them named (or not named) "graphic". They are embedded, and they keep trading places, Ann's signature following Tracy's name, Tracy's signature following Lila's name etc. If I keep playing with it, I get lucky and each one ends up in its proper frame, but I haven't been lucky that much, and I'd prefer to just fix it.

       

      Normally when I encounter embedded graphics, I just unembed them. These are something special that resists unembedding, gives me a message of "Indesign cannot unembed some of the links because they do not have a name". Is there any way to unembed a graphic like this? Is there a way to give it a name so I can unembed it? Here's a link to a blank page with one of these on it:

       

      https://www.dropbox.com/s/bbqvdm7bpzgto05/cant-unembed.indd?dl=0

        • 1. Re: Can't unembed link
          SJRiegel Adobe Community Professional & MVP

          I could not get it to un-embed, but I was able to copy it and paste it into Photoshop.

          Make sure your InDesign Clipboard Handling preferences are set to Copy PDF to Clipboard.

           

          You can then copy the signatures and paste each into its own new Photoshop document.

          • 2. Re: Can't unembed link
            rob day Adobe Community Professional & MVP

            If you are using OSX I can post an AppleScript that will unembed them.

            • 3. Re: Can't unembed link
              Kenneth C. Benson Level 4

              Thanks, SJ. I ended up exporting to PDF and then opening the PDF in Photoshop. Your method is probably better, though. I had to guess at the resolution.

              • 4. Re: Can't unembed link
                Laubender Adobe Community Professional & MVP

                Hi Kenneth,

                why do you had to guess the resolution?

                 

                Just open the Links panel and check the pixel dimensions:

                720 x 301 px

                 

                Do a page size like that with InDesign

                Scale the image to that size and position it at x/y: 0,0

                Export to PDF.

                Open with PhotoShop as a 720 x 301 px image in Grayscale mode.

                Change Mode to Bitmap 1-Bit.

                 

                Save with a new name as TIFF image.

                 

                FWIW: Copy/paste from InDesign to PhotoShop results in the wrong ratio and size:

                728 x 246 px

                 

                Regards,
                Uwe

                • 5. Re: Can't unembed link
                  rob day Adobe Community Professional & MVP

                  Uwe, A while back there was a question about saving pasted graphics and replacing them as links. I wrote this AppleScript that gets the complete PDF info from pasted graphics then saves & links. It also seems to work in this case. I checked the saved PDF after running the script and the Black & White bitmap is there at its original pixel dimensions.

                   

                  Here's the script:

                   

                  tell application "Adobe InDesign CC 2014"

                      --make sure the clipboard pref is copy PDF

                      set MyClipPref to copy PDF to clipboard of clipboard preferences

                      set copy PDF to clipboard of clipboard preferences to true

                    

                      --where to copy embedded files

                      set myFolder to (choose folder with prompt "Please select the folder you want to save your PDF pages in") as string

                      set myDocument to active document

                    

                      --get all of the doc's page items

                      set pitems to all page items of every page item of myDocument

                    

                      --empty path and image name lists for linking later

                      set imagePaths to {}

                      set copiedimages to {}

                    

                      repeat with i from 1 to number of items in pitems

                        

                          -- a placed item is item 1 of the page item, try skips everything else

                          try

                              set myPic to item 1 of item i of pitems

                            

                              --the placed file's item link, pasted files return nothing

                              set x to item link of myPic

                            

                              --check for pasted or embedded files,

                              if x is nothing or status of x is link embedded then

                                

                                  --select the placed for copying

                                  select myPic

                                

                                  --the the link id to use as a name

                                  set myname to id of myPic

                                

                                  --the scale

                                  set hs to horizontal scale of myPic

                                  set vs to vertical scale of myPic

                                

                                  --temporarily set the scale to 100% so the copy is the original actual resolution

                                  set horizontal scale of myPic to 100

                                  set vertical scale of myPic to 100

                                

                                  --copy and reset the scale

                                  copy

                                  set horizontal scale of myPic to hs

                                  set vertical scale of myPic to vs

                                

                                  --save the clipboard as a PDF

                                  tell application "Finder"

                                      my saveImage(myFolder, myname)

                                  end tell

                                

                                  --save the paths and images as lists for linking

                                  set end of imagePaths to myFolder & myname & ".pdf"

                                  set end of copiedimages to myPic

                              end if

                          end try

                      end repeat

                    

                      --link the saved files

                      repeat with j from 1 to number of items in imagePaths

                          set itemlink to item j of imagePaths

                          place alias itemlink on item j of copiedimages

                      end repeat

                    

                      --reset preference

                      set copy PDF to clipboard of clipboard preferences to MyClipPref

                  end tell

                   

                  --writes clipboard to disk

                  --save folder, image name

                  on saveImage(theFolder, filename)

                      --the save path

                      set myPath to theFolder & filename & ".pdf"

                      try

                          set myFile to (open for access myPath with write permission)

                          set eof myFile to 0

                          write (the clipboard as «class PDF ») to myFile -- as whatever

                          close access myFile

                          return (POSIX path of myPath)

                      on error

                          try

                              close access myFile

                          end try

                          return ""

                      end try

                  end saveImage

                  • 6. Re: Can't unembed link
                    Laubender Adobe Community Professional & MVP

                    Hi Rob,

                    thank you very much for this!

                     

                    Just tested your script on the original InDesign document provided by Kenneth.
                    German InDesign CS6 8.1 on OSX 10.6.8.

                     

                    All went great!
                    Name of exported PDF is 213.pdf according to the ID number of the embedded image.

                     

                    The next step would be to extract the bitmap from the PDF and saving it as 1-Bit TIFF for further usage with InDesign (to color it perhaps). Currently I can only test with Acrobat 9 and X. But for this kind of bitmap Acrobat is not able to hand this job over to PhotoShop directly. Maybe because of the image mask, maybe because of the 1-Bit nature of the image.

                     

                    Will test later with Acrobat Pro DC.

                     

                    So we would open and render the PDF with PhotoShop according to the original pixel dimensions:

                    720 x 301 px

                     

                    For this kind of image one has to look up the numbers, because PhotoShop CS6 will suggest different ones. And if one is following PhotoShop's guess the aspect ratio would be different and pixels would be changed.


                    My assumption here is that the pixels were built of square shapes.

                     

                    Thanks,
                    Uwe

                    • 7. Re: Can't unembed link
                      rob day Adobe Community Professional & MVP

                      But for this kind of bitmap Acrobat is not able to hand this job over to PhotoShop directly. Maybe because of the image mask, maybe because of the 1-Bit nature of the image.

                      Looks like it's coming from a fax, which might explain the missing name and weird aspect ratio? I don't think the OP needs the bitmap—it's the embedded graphics all named the same causing a problem in the layout.

                       

                      Screen Shot 2017-03-08 at 4.04.04 PM.png